gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/Reg.asp

    <!--#include file="Head.asp"-->
<!--#include file="Inc/Md5.asp"-->
<!--#include file="Function.asp"-->
<!--#include file="Api/Api_Class.asp"-->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

With Netout
	.Load("Comm")
	If Config.Settings(7) = "0" Then
		.ShowErr(1)
		Response.End()
	End If
	Dim Action,Html,rs
	Action = .CheckStr(request.QueryString("Action"),"")
	If Action = "SaveReg" Then
		UserName = .ReplaceBadChar(trim(request.Form("UserName")))
		Password = .ReplaceBadChar(trim(Request.Form("Password")))
		PrePassword = .ReplaceBadChar(trim(Request.Form("PrePassword")))
		If .strLength(UserName)<4 Or .strLength(UserName)>20 Then
			.ShowErr(2)
			Response.End()
		End If
		If Len(Password)<6 Or Len(Password)>16 Then
			.ShowErr(3)
			Response.End()
		End If
		If Password<>PrePassword Then
			.ShowErr(4)
			Response.End()
		End If
		
		TrueName = Server.HTMLEncode(Trim(Request.Form("TrueName")))
		ManuName = Server.HTMLEncode(Trim(Request.Form("ManuName")))
		Email = Trim(Request.Form("Email"))
		UserPic = Trim(Request.Form("Image"))
		Question = Request.Form("Question")
		Answer = Request.Form("Answer")
		Phone = Request.Form("Phone")
		Mobile = Request.Form("Mobile")
		Desc = .HtmlEncode(Trim(Request.Form("Desc")),True)
		
		PrePassword = MD5(Password,Api_Md5_Len)
		
		Set Rs = server.createobject("adodb.recordset")
		Rs.open "select * from NT_User where UserName='"&UserName&"'",conn,1,3
		If Rs.eof Or Rs.eof Then
			'-----------------------------------------------------------------
			'系统整合
			'-----------------------------------------------------------------
			Dim objApi,Api_SaveCookie,SysKey
			If Api_Enable Then
				Set objApi = New Lyout_Api
				
				objApi.NodeValue "action","reguser",0,False
				objApi.NodeValue "username",UserName,1,False
				objApi.NodeValue "truename",TrueName,1,False
				
				Md5OLD = 1
				SysKey = Md5(objApi.XmlNode("username")&Api_SysKey,Api_Md5_Len)
				Md5OLD = 0
				
				objApi.NodeValue "syskey",SysKey,0,False
				objApi.NodeValue "password",Password,0,False
				objApi.NodeValue "email",Email,1,False
				objApi.NodeValue "question",Question,1,False
				objApi.NodeValue "answer",Answer,1,False
				objApi.NodeValue "mobile",Mobile,1,False
				objApi.NodeValue "phone",Phone,1,False
				objApi.SendHttpData
				
				If objApi.Status = "1" Then
					Netout.ShowError(objApi.Message)
					Response.End()
				Else
					Response.Write(objApi.SetCookie(SysKey,UserName,PrePassword,Request("usercookies")))
				End If
				Set objApi = Nothing
			End If

			Dim urs
			Set urs = Conn.Execute("select GroupName,Setting from NT_UserGroup where ID=4")
			
			Rs.addnew
			Rs("UserName") = UserName
			Rs("TrueName") = TrueName
			Rs("ManuName") = ManuName
			Rs("Password") = PrePassword
			Rs("UserEmail") = Email
			Rs("UserPic") = UserPic
			Rs("Phone") = Phone
			Rs("Mobile") = Mobile
			Rs("Setting") = urs(1)
			Rs("GroupID") = 4
			Rs("Question") = Question
			Rs("Answer") = MD5(Answer,Api_Md5_Len)
			Rs("userDesc") = Desc
			Rs.Update
			
			Setting = split(urs(1),",")
	
			.SetCookie "UserId",		.GetScalar("Select Max(Id) from Nt_User")
			.SetCookie "UserName",		UserName
			.SetPurview urs(1)
			.SetCookie "GroupID",		4
			.SetCookie "Group",			urs(0)
			
			Set urs = Nothing
			
			Response.Write("<script>alert('"&.theCode(4)&"');this.location.href='./';</script>")
		Else
			.ShowErr(5)
		End If		
		Rs.Close
		Set Rs = Nothing
		Response.End()
	Else
		If Action = "" Then
			Set rs = Conn.Execute("select RegInfo from Nt_Config")
			theHtml = replace(Template.Html(7),"{?RegInfo}",Netout.HtmlCode(Netout.HtmlEncode(rs(0)&"",False),True))
			set rs = Nothing
		ElseIf Action = "Reg" Then 
			theHtml = Template.Html(8)
		End If
		MyHtml = Replace(Replace(Split(Template.Html(0),"||")(0),"{?left_beg}",""),"{?left_end}","")
		MyHtml = Replace(MyHtml,"{?RightInfo}",theHtml)
		MyHtml = Replace(MyHtml,"{?LeftInfo}",Replace(Template.Html(1),"{?QuickLaunch}",QuickLaunch()))
		MyHtml = Replace(.TempHtml,"{?CurrentScript}",MyHtml)
		Response.Write(MyHtml)
	End If
End With
Set Template = Nothing
Set Netout = Nothing
%>